home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / ctrsv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  10.4 KB  |  328 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE CTRSV ( UPLO, TRANS, DIAG, N, A, LDA, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, LDA, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       COMPLEX            A( LDA, * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  CTRSV  solves one of the systems of equations
  16. *
  17. *     A*x = b,   or   A'*x = b,   or   conjg( A' )*x = b,
  18. *
  19. *  where b and x are n element vectors and A is an n by n unit, or
  20. *  non-unit, upper or lower triangular matrix.
  21. *
  22. *  No test for singularity or near-singularity is included in this
  23. *  routine. Such tests must be performed before calling this routine.
  24. *
  25. *  Parameters
  26. *  ==========
  27. *
  28. *  UPLO   - CHARACTER*1.
  29. *           On entry, UPLO specifies whether the matrix is an upper or
  30. *           lower triangular matrix as follows:
  31. *
  32. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  33. *
  34. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  35. *
  36. *           Unchanged on exit.
  37. *
  38. *  TRANS  - CHARACTER*1.
  39. *           On entry, TRANS specifies the equations to be solved as
  40. *           follows:
  41. *
  42. *              TRANS = 'N' or 'n'   A*x = b.
  43. *
  44. *              TRANS = 'T' or 't'   A'*x = b.
  45. *
  46. *              TRANS = 'C' or 'c'   conjg( A' )*x = b.
  47. *
  48. *           Unchanged on exit.
  49. *
  50. *  DIAG   - CHARACTER*1.
  51. *           On entry, DIAG specifies whether or not A is unit
  52. *           triangular as follows:
  53. *
  54. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  55. *
  56. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  57. *                                  triangular.
  58. *
  59. *           Unchanged on exit.
  60. *
  61. *  N      - INTEGER.
  62. *           On entry, N specifies the order of the matrix A.
  63. *           N must be at least zero.
  64. *           Unchanged on exit.
  65. *
  66. *  A      - COMPLEX          array of DIMENSION ( LDA, n ).
  67. *           Before entry with  UPLO = 'U' or 'u', the leading n by n
  68. *           upper triangular part of the array A must contain the upper
  69. *           triangular matrix and the strictly lower triangular part of
  70. *           A is not referenced.
  71. *           Before entry with UPLO = 'L' or 'l', the leading n by n
  72. *           lower triangular part of the array A must contain the lower
  73. *           triangular matrix and the strictly upper triangular part of
  74. *           A is not referenced.
  75. *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
  76. *           A are not referenced either, but are assumed to be unity.
  77. *           Unchanged on exit.
  78. *
  79. *  LDA    - INTEGER.
  80. *           On entry, LDA specifies the first dimension of A as declared
  81. *           in the calling (sub) program. LDA must be at least
  82. *           max( 1, n ).
  83. *           Unchanged on exit.
  84. *
  85. *  X      - COMPLEX          array of dimension at least
  86. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  87. *           Before entry, the incremented array X must contain the n
  88. *           element right-hand side vector b. On exit, X is overwritten
  89. *           with the solution vector x.
  90. *
  91. *  INCX   - INTEGER.
  92. *           On entry, INCX specifies the increment for the elements of
  93. *           X. INCX must not be zero.
  94. *           Unchanged on exit.
  95. *
  96. *
  97. *  Level 2 Blas routine.
  98. *
  99. *  -- Written on 22-October-1986.
  100. *     Jack Dongarra, Argonne National Lab.
  101. *     Jeremy Du Croz, Nag Central Office.
  102. *     Sven Hammarling, Nag Central Office.
  103. *     Richard Hanson, Sandia National Labs.
  104. *
  105. *
  106. *     .. Parameters ..
  107.       COMPLEX            ZERO
  108.       PARAMETER        ( ZERO = ( 0.0E+0, 0.0E+0 ) )
  109. *     .. Local Scalars ..
  110.       COMPLEX            TEMP
  111.       INTEGER            I, INFO, IX, J, JX, KX
  112.       LOGICAL            NOCONJ, NOUNIT
  113. *     .. External Functions ..
  114.       LOGICAL            LSAME
  115.       EXTERNAL           LSAME
  116. *     .. External Subroutines ..
  117.       EXTERNAL           XERBLA
  118. *     .. Intrinsic Functions ..
  119.       INTRINSIC          CONJG, MAX
  120. *     ..
  121. *     .. Executable Statements ..
  122. *
  123. *     Test the input parameters.
  124. *
  125.       INFO = 0
  126.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  127.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  128.          INFO = 1
  129.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  130.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  131.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  132.          INFO = 2
  133.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  134.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  135.          INFO = 3
  136.       ELSE IF( N.LT.0 )THEN
  137.          INFO = 4
  138.       ELSE IF( LDA.LT.MAX( 1, N ) )THEN
  139.          INFO = 6
  140.       ELSE IF( INCX.EQ.0 )THEN
  141.          INFO = 8
  142.       END IF
  143.       IF( INFO.NE.0 )THEN
  144.          CALL XERBLA( 'CTRSV ', INFO )
  145.          RETURN
  146.       END IF
  147. *
  148. *     Quick return if possible.
  149. *
  150.       IF( N.EQ.0 )
  151.      $   RETURN
  152. *
  153.       NOCONJ = LSAME( TRANS, 'T' )
  154.       NOUNIT = LSAME( DIAG , 'N' )
  155. *
  156. *     Set up the start point in X if the increment is not unity. This
  157. *     will be  ( N - 1 )*INCX  too small for descending loops.
  158. *
  159.       IF( INCX.LE.0 )THEN
  160.          KX = 1 - ( N - 1 )*INCX
  161.       ELSE IF( INCX.NE.1 )THEN
  162.          KX = 1
  163.       END IF
  164. *
  165. *     Start the operations. In this version the elements of A are
  166. *     accessed sequentially with one pass through A.
  167. *
  168.       IF( LSAME( TRANS, 'N' ) )THEN
  169. *
  170. *        Form  x := inv( A )*x.
  171. *
  172.          IF( LSAME( UPLO, 'U' ) )THEN
  173.             IF( INCX.EQ.1 )THEN
  174.                DO 20, J = N, 1, -1
  175.                   IF( X( J ).NE.ZERO )THEN
  176.                      IF( NOUNIT )
  177.      $                  X( J ) = X( J )/A( J, J )
  178.                      TEMP = X( J )
  179.                      DO 10, I = J - 1, 1, -1
  180.                         X( I ) = X( I ) - TEMP*A( I, J )
  181.    10                CONTINUE
  182.                   END IF
  183.    20          CONTINUE
  184.             ELSE
  185.                JX = KX + ( N - 1 )*INCX
  186.                DO 40, J = N, 1, -1
  187.                   IF( X( JX ).NE.ZERO )THEN
  188.                      IF( NOUNIT )
  189.      $                  X( JX ) = X( JX )/A( J, J )
  190.                      TEMP = X( JX )
  191.                      IX   = JX
  192.                      DO 30, I = J - 1, 1, -1
  193.                         IX      = IX      - INCX
  194.                         X( IX ) = X( IX ) - TEMP*A( I, J )
  195.    30                CONTINUE
  196.                   END IF
  197.                   JX = JX - INCX
  198.    40          CONTINUE
  199.             END IF
  200.          ELSE
  201.             IF( INCX.EQ.1 )THEN
  202.                DO 60, J = 1, N
  203.                   IF( X( J ).NE.ZERO )THEN
  204.                      IF( NOUNIT )
  205.      $                  X( J ) = X( J )/A( J, J )
  206.                      TEMP = X( J )
  207.                      DO 50, I = J + 1, N
  208.                         X( I ) = X( I ) - TEMP*A( I, J )
  209.    50                CONTINUE
  210.                   END IF
  211.    60          CONTINUE
  212.             ELSE
  213.                JX = KX
  214.                DO 80, J = 1, N
  215.                   IF( X( JX ).NE.ZERO )THEN
  216.                      IF( NOUNIT )
  217.      $                  X( JX ) = X( JX )/A( J, J )
  218.                      TEMP = X( JX )
  219.                      IX   = JX
  220.                      DO 70, I = J + 1, N
  221.                         IX      = IX      + INCX
  222.                         X( IX ) = X( IX ) - TEMP*A( I, J )
  223.    70                CONTINUE
  224.                   END IF
  225.                   JX = JX + INCX
  226.    80          CONTINUE
  227.             END IF
  228.          END IF
  229.       ELSE
  230. *
  231. *        Form  x := inv( A' )*x  or  x := inv( conjg( A' ) )*x.
  232. *
  233.          IF( LSAME( UPLO, 'U' ) )THEN
  234.             IF( INCX.EQ.1 )THEN
  235.                DO 110, J = 1, N
  236.                   TEMP = X( J )
  237.                   IF( NOCONJ )THEN
  238.                      DO 90, I = 1, J - 1
  239.                         TEMP = TEMP - A( I, J )*X( I )
  240.    90                CONTINUE
  241.                      IF( NOUNIT )
  242.      $                  TEMP = TEMP/A( J, J )
  243.                   ELSE
  244.                      DO 100, I = 1, J - 1
  245.                         TEMP = TEMP - CONJG( A( I, J ) )*X( I )
  246.   100                CONTINUE
  247.                      IF( NOUNIT )
  248.      $                  TEMP = TEMP/CONJG( A( J, J ) )
  249.                   END IF
  250.                   X( J ) = TEMP
  251.   110          CONTINUE
  252.             ELSE
  253.                JX = KX
  254.                DO 140, J = 1, N
  255.                   IX   = KX
  256.                   TEMP = X( JX )
  257.                   IF( NOCONJ )THEN
  258.                      DO 120, I = 1, J - 1
  259.                         TEMP = TEMP - A( I, J )*X( IX )
  260.                         IX   = IX   + INCX
  261.   120                CONTINUE
  262.                      IF( NOUNIT )
  263.      $                  TEMP = TEMP/A( J, J )
  264.                   ELSE
  265.                      DO 130, I = 1, J - 1
  266.                         TEMP = TEMP - CONJG( A( I, J ) )*X( IX )
  267.                         IX   = IX   + INCX
  268.   130                CONTINUE
  269.                      IF( NOUNIT )
  270.      $                  TEMP = TEMP/CONJG( A( J, J ) )
  271.                   END IF
  272.                   X( JX ) = TEMP
  273.                   JX      = JX   + INCX
  274.   140          CONTINUE
  275.             END IF
  276.          ELSE
  277.             IF( INCX.EQ.1 )THEN
  278.                DO 170, J = N, 1, -1
  279.                   TEMP = X( J )
  280.                   IF( NOCONJ )THEN
  281.                      DO 150, I = N, J + 1, -1
  282.                         TEMP = TEMP - A( I, J )*X( I )
  283.   150                CONTINUE
  284.                      IF( NOUNIT )
  285.      $                  TEMP = TEMP/A( J, J )
  286.                   ELSE
  287.                      DO 160, I = N, J + 1, -1
  288.                         TEMP = TEMP - CONJG( A( I, J ) )*X( I )
  289.   160                CONTINUE
  290.                      IF( NOUNIT )
  291.      $                  TEMP = TEMP/CONJG( A( J, J ) )
  292.                   END IF
  293.                   X( J ) = TEMP
  294.   170          CONTINUE
  295.             ELSE
  296.                KX = KX + ( N - 1 )*INCX
  297.                JX = KX
  298.                DO 200, J = N, 1, -1
  299.                   IX   = KX
  300.                   TEMP = X( JX )
  301.                   IF( NOCONJ )THEN
  302.                      DO 180, I = N, J + 1, -1
  303.                         TEMP = TEMP - A( I, J )*X( IX )
  304.                         IX   = IX   - INCX
  305.   180                CONTINUE
  306.                      IF( NOUNIT )
  307.      $                  TEMP = TEMP/A( J, J )
  308.                   ELSE
  309.                      DO 190, I = N, J + 1, -1
  310.                         TEMP = TEMP - CONJG( A( I, J ) )*X( IX )
  311.                         IX   = IX   - INCX
  312.   190                CONTINUE
  313.                      IF( NOUNIT )
  314.      $                  TEMP = TEMP/CONJG( A( J, J ) )
  315.                   END IF
  316.                   X( JX ) = TEMP
  317.                   JX      = JX   - INCX
  318.   200          CONTINUE
  319.             END IF
  320.          END IF
  321.       END IF
  322. *
  323.       RETURN
  324. *
  325. *     End of CTRSV .
  326. *
  327.       END
  328.